VLIDE debug part1

Небольшая отладка по VLIDE. Пример высосан из пальца, частично используется собственный фреймворк.



Сайт: https://autolisp.ru

Исходный код (без вставки анонимного блока):
(defun _kpblc-create-table (titles data / adoc def table col row ref)
;|
* Создать таблицу по данным
* Параметры вызова:
titles ; заголовки столбцов по принципу ("Заголовок" . [Ширина, мм])
data ; список вносимых данных
* Примеры вызова:
(_kpblc-create-table
'(("Поз" . 15) ("Наименование" . 65) ("Ед.изм." . 20) ("Кол") ("Прим." . 20))
'((1 "Что-то под номером 1" "Да" nil "Типа того") (2 "нумер два" "кг" 16.69))
) ;_ end of _kpblc-create-table
|;
(setq adoc (vla-get-activedocument (vlax-get-acad-object))
def (vla-add (vla-get-blocks adoc) (vlax-3d-point '(0. 0. 0.)) "*U")
table (vla-addtable def (vlax-3d-point 0. 0. 0.) (+ 2 (length data)) (length titles) 8.0 15.)
) ;_ end of setq
(setq row 1
col 0
) ;_ end of setq
(vla-put-regeneratetablesuppressed table :vlax-true)
(foreach item titles
(vla-setcolumnwidth
table
col
(cond ((cdr item))
(t 15.)
) ;_ end of cond
) ;_ end of vla-setcolumnwidth
(vla-setcellvalue table row col (car item))
(setq col (1+ col))
) ;_ end of foreach
(setq row 2
col 0
) ;_ end of setq
(foreach row_item data
(foreach item row_item
(vla-setcellvalue
table
row
col
(cond ((not item) "")
((= (type item) 'int) (itoa item))
((= (type item) 'real) (rtos item 2 14))
(t item)
) ;_ end of cond
) ;_ end of vla-setcellvalue
(setq col (1+ col))
) ;_ end of foreach
(setq row (1+ row)
col 0
) ;_ end of setq
) ;_ end of foreach
(vla-scaleentity table (vlax-3d-point '(0. 0. 0.)) (getvar "dimscale"))
(vla-put-regeneratetablesuppressed table :vlax-false)
(vla-update table)
;; Тут прописывается собственная вставка блока
) ;_ end of defun